REM Level Skybird's Other Side
REM	Skybird's Other Side 2.0.0
REM	Author: Kief, Created on 26 Jul 2007
REM	messages added via pot file by dayokay Dec2020

SET_GENERATE_SPEED(1500)

MAX_CREATURES(PLAYER0,25)
MAX_CREATURES(PLAYER1,30)

START_MONEY(PLAYER1,20000)
START_MONEY(PLAYER0,2460000)

COMPUTER_PLAYER(PLAYER1,1)

ADD_CREATURE_TO_POOL(TROLL,30)
ADD_CREATURE_TO_POOL(SORCEROR,17)
ADD_CREATURE_TO_POOL(BILE_DEMON,20)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,30)
ADD_CREATURE_TO_POOL(DRAGON,21)
ADD_CREATURE_TO_POOL(HELL_HOUND,30)
ADD_CREATURE_TO_POOL(ORC,17)


CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,1)
CREATURE_AVAILABLE(PLAYER1,SORCEROR,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,1)
CREATURE_AVAILABLE(PLAYER1,DARK_MISTRESS,1,1)
CREATURE_AVAILABLE(PLAYER1,VAMPIRE,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,DRAGON,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,HELL_HOUND,1,1)
CREATURE_AVAILABLE(PLAYER0,ORC,1,1)

ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)
ROOM_AVAILABLE(PLAYER1,BRIDGE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,PRISON,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,SCAVENGER,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GRAVEYARD,1,0)


REM Spells

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(PLAYER1,POWER_SIGHT,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DISEASE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CAVE_IN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CHICKEN,1,0)


REM doors & traps

TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)


CREATE_PARTY(RPG)
    ADD_TO_PARTY(RPG,WIZARD,10,300,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(RPG,BARBARIAN,10,300,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(RPG,KNIGHT,10,300,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(RPG,WITCH,10,300,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(BIG_BOY)
    ADD_TO_PARTY(BIG_BOY,AVATAR,10,300,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(BIG_BOY,BARBARIAN,10,300,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(BRUTES)
    ADD_TO_PARTY(BRUTES,GIANT,10,500,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(BRUTES,GIANT,10,500,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(BRUTES,BARBARIAN,10,500,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(BRUTES,BARBARIAN,10,500,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(MAGIC)
    ADD_TO_PARTY(MAGIC,WIZARD,10,550,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MAGIC,KNIGHT,10,550,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MAGIC,WITCH,10,550,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MAGIC,SAMURAI,10,550,ATTACK_DUNGEON_HEART,0)


CREATE_PARTY(DWARF)
    ADD_TO_PARTY(DWARF,DWARFA,9,650,STEAL_GOLD,0)
    ADD_TO_PARTY(DWARF,DWARFA,9,650,STEAL_GOLD,0)
    ADD_TO_PARTY(DWARF,THIEF,9,3000,STEAL_GOLD,0)
    ADD_TO_PARTY(DWARF,THIEF,9,3000,STEAL_GOLD,0)

DISPLAY_OBJECTIVE(68,PLAYER0)

IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
    ROOM_AVAILABLE(PLAYER0,BRIDGE,1,1)
    SET_FLAG(PLAYER_GOOD,FLAG0,1)
    DISPLAY_OBJECTIVE(69,PLAYER_GOOD)
    ADD_CREATURE_TO_LEVEL(PLAYER1,VAMPIRE,PLAYER1,1,10,0)
    CREATURE_AVAILABLE(PLAYER0,DARK_MISTRESS,1,1)
ENDIF

IF(PLAYER_GOOD,AVATAR == 0)
    SET_FLAG(PLAYER_GOOD,FLAG1,1)
    SET_TIMER(PLAYER_GOOD,TIMER0)
    DISPLAY_OBJECTIVE(72,PLAYER0)
ENDIF

IF(PLAYER_GOOD,FLAG1 == 1)
    IF(PLAYER_GOOD,TIMER0 >= 1000)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MAGIC,-1,1)
        ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,BRUTES,-2,DUNGEON,1,10,100)
        ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,DWARF,-3,DUNGEON,1,10,100)
        ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,DWARF,-6,DUNGEON,1,10,100)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,BRUTES,1,1)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MAGIC,2,1)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,BRUTES,4,1)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DWARF,3,1)
    ENDIF
    IF(PLAYER_GOOD,TIMER0 >= 1133)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DWARF,3,1)
        SET_FLAG(PLAYER_GOOD,FLAG2,1)
        DISPLAY_OBJECTIVE(71,PLAYER0)
        REM	PRINT("HA HA ROBBO (LOW COUNT) YOU ARE DEAD ")
    ENDIF
    IF(PLAYER_GOOD,TIMER0 >= 1366)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DWARF,3,1)
        SET_FLAG(PLAYER_GOOD,FLAG2,1)
    ENDIF
    IF(PLAYER_GOOD,TIMER0 >= 1466)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DWARF,3,1)
        SET_FLAG(PLAYER_GOOD,FLAG2,1)
    ENDIF
    IF(PLAYER_GOOD,TIMER0 >= 1600)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,RPG,3,1)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,BIG_BOY,3,1)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MAGIC,2,1)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,BRUTES,4,1)
        SET_FLAG(PLAYER_GOOD,FLAG2,1)
        DISPLAY_OBJECTIVE(73,PLAYER0)
    ENDIF
ENDIF


IF(PLAYER_GOOD,FLAG2 == 1)
    IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
        IF(PLAYER_GOOD,AVATAR == 0)
            DISPLAY_OBJECTIVE(70,PLAYER0)
            WIN_GAME
        ENDIF
    ENDIF
ENDIF

IF(PLAYER0,DUNGEON_DESTROYED == 1)
    LOSE_GAME
ENDIF
